::[Bat To Exe Converter]
::
::YAwzoRdxOk+EWAjk
::fBw5plQjdCyDJGyX8VAjFBdBRReaAE+1EbsQ5+n//NaVp0ASQuctR5vJ27CbI+EcpEznevY=
::YAwzuBVtJxjWCl3EqQJgSA==
::ZR4luwNxJguZRRnk
::Yhs/ulQjdF+5
::cxAkpRVqdFKZSjk=
::cBs/ulQjdF+5
::ZR41oxFsdFKZSDk=
::eBoioBt6dFKZSDk=
::cRo6pxp7LAbNWATEpCI=
::egkzugNsPRvcWATEpCI=
::dAsiuh18IRvcCxnZtBJQ
::cRYluBh/LU+EWAnk
::YxY4rhs+aU+JeA==
::cxY6rQJ7JhzQF1fEqQJQ
::ZQ05rAF9IBncCkqN+0xwdVs0
::ZQ05rAF9IAHYFVzEqQJQ
::eg0/rx1wNQPfEVWB+kM9LVsJDGQ=
::fBEirQZwNQPfEVWB+kM9LVsJDGQ=
::cRolqwZ3JBvQF1fEqQJQ
::dhA7uBVwLU+EWDk=
::YQ03rBFzNR3SWATElA==
::dhAmsQZ3MwfNWATElA==
::ZQ0/vhVqMQ3MEVWAtB9wSA==
::Zg8zqx1/OA3MEVWAtB9wSA==
::dhA7pRFwIByZRRnk
::Zh4grVQjdCyDJGyX8VAjFBdBRReaAE+1EbsQ5+n//Na1p0ASQuctOLvJ27CbgyewKUqkRrVj02Jf+A==
::YB416Ek+ZG8=
::
::
::978f952a14a936cc963da21a135fa983
@echo off
setlocal enabledelayedexpansion

cls
echo ================================================
echo   Star Citizen - Removedor de Traducao PT-BR
echo ================================================
echo:
echo Procurando a pasta do Star Citizen...
echo:

rem === Encontrar pasta do Star Citizen automaticamente ===
set "GAME_DATA="

for %%D in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist "%%D:\Program Files\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\Program Files (x86)\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files (x86)\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\StarCitizen\LIVE\data"
  )
)

if not defined GAME_DATA (
  for %%D in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%D:\Program Files\Roberts Space Industries\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files\Roberts Space Industries\StarCitizen\PTU\data"
    )
    if exist "%%D:\Roberts Space Industries\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\Roberts Space Industries\StarCitizen\PTU\data"
    )
    if exist "%%D:\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\StarCitizen\PTU\data"
    )
  )
)

if not defined GAME_DATA (
  echo:
  echo [ERRO] Nao foi possivel encontrar a pasta do Star Citizen.
  echo Verifique se o jogo esta instalado.
  echo:
  pause
  exit /b
)

echo Pasta encontrada: !GAME_DATA!
echo:

set "LANG_DIR=!GAME_DATA!\Localization"
set "USER_CFG=!GAME_DATA!\..\user.cfg"
set "TEMP_CFG=!GAME_DATA!\..\user.cfg.new"

IF EXIST "!LANG_DIR!" (
  echo Removendo arquivos de traducao...
  RD /S /Q "!LANG_DIR!"
)

IF EXIST "!USER_CFG!" (
  echo Removendo configuracao de idioma...
  IF EXIST "!TEMP_CFG!" DEL /F "!TEMP_CFG!"
  findstr /v /i "^g_language" "!USER_CFG!" > "!TEMP_CFG!"
  for %%F in ("!TEMP_CFG!") do set "FSIZE=%%~zF"
  if "!FSIZE!"=="0" (
    DEL /F "!TEMP_CFG!"
    DEL /F "!USER_CFG!"
  ) else (
    move /y "!TEMP_CFG!" "!USER_CFG!" > nul
  )
)

echo:
echo ================================================
echo   Traducao removida. O jogo voltou ao ingles.
echo ================================================
echo:
pause
endlocal