@echo off
setlocal enabledelayedexpansion

cls
echo ================================================
echo   Star Citizen - Atualizador de Traducao PT-BR
echo ================================================
echo:
echo Procurando a pasta do Star Citizen...
echo:

rem === Encontrar pasta do Star Citizen automaticamente ===
set "GAME_DATA="

for %%D in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist "%%D:\Program Files\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\Program Files (x86)\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files (x86)\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\Roberts Space Industries\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\Roberts Space Industries\StarCitizen\LIVE\data"
  )
  if exist "%%D:\StarCitizen\LIVE\data" (
    if not defined GAME_DATA set "GAME_DATA=%%D:\StarCitizen\LIVE\data"
  )
)

if not defined GAME_DATA (
  for %%D in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%D:\Program Files\Roberts Space Industries\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\Program Files\Roberts Space Industries\StarCitizen\PTU\data"
    )
    if exist "%%D:\Roberts Space Industries\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\Roberts Space Industries\StarCitizen\PTU\data"
    )
    if exist "%%D:\StarCitizen\PTU\data" (
      if not defined GAME_DATA set "GAME_DATA=%%D:\StarCitizen\PTU\data"
    )
  )
)

if not defined GAME_DATA (
  echo:
  echo [ERRO] Nao foi possivel encontrar a pasta do Star Citizen.
  echo Verifique se o jogo esta instalado.
  echo:
  pause
  exit /b
)

echo Pasta encontrada: !GAME_DATA!
echo:

set "language=portuguese_(brazil)"
set "LANG_DIR=!GAME_DATA!\Localization\!language!"

IF NOT EXIST "!LANG_DIR!" (
  echo:
  echo [ERRO] A traducao nao esta instalada.
  echo Use o instalador primeiro.
  echo:
  pause
  exit /b
)

echo Baixando versao mais recente...
curl -L -s -o "!GAME_DATA!\global.ini" "https://raw.githubusercontent.com/danielgmota/StarCitizen-Localization/develop/data/Localization/portuguese_(brazil)/global.ini"

IF NOT EXIST "!GAME_DATA!\global.ini" (
  echo:
  echo [ERRO] Nao foi possivel baixar a traducao.
  echo Verifique sua conexao com a internet.
  echo:
  pause
  exit /b
)

move /y "!GAME_DATA!\global.ini" "!LANG_DIR!\global.ini" > nul

echo:
echo ================================================
echo   Traducao atualizada com sucesso! Bom jogo!
echo ================================================
echo:
pause
endlocal